WPS TEXTJOIN()函数的用法（附带实例）

TEXTJOIN() 函数可以指定分隔符将多个字符串连接，函数语法格式如下：

=TEXTJOIN(分隔符，忽略空白单元格，字符串1, …)

• 分隔符（必填项）：数值、字符串、数组、单元格区域，省略参数时，默认值（空文本）；
• 忽略空白单元格：TRUE 表示忽略空值，FALSE 表示包含空值，省略参数时，默认值（TRUE）；
• 字符串1（必填项）：数值、字符串、数组、单元格区域。

【实例】将省、市、区/县合并到一列。在 F5 单元格输入公式：

=TEXTJOIN("-",TRUE,C5:E5)

效果如下图所示：


第 1 个参数设置“–”符号作为分隔符，第 2 个参数设置为 TRUE（忽略空值），第 3 个参数引用 C5:E5 单元格区域，即可将省、市、区/县连接到一个单元格中。

【实例 2】将每位学生报名的科目合并到一个单元格。在 H15 单元格输入公式：

=TEXTJOIN("、",TRUE,IF(C15:G15="√",$C$14:$G$14,""))

效果如下图所示：


使用 IF() 函数判断 C15:G15 单元格区域是否等于 √，若条件成立则返回对应的 C14:G14 单元格区域，因为公式需要向下填充，所以 C14:G14 单元格需要设置绝对引用，条件不成立时，返回空文本，返回的数组作为 TEXTJOIN() 函数的第 3 个参数，第 1 个参数分隔符设置为“、”，第 2 个参数设置为 TRUE（忽略空值），即可将每位学生报名的名科目合并到一个单元格。

【实例 3】查询每个项目所有参与人员。在 G25 单元格输入公式：

=TEXTJOIN("、",TRUE,FILTER($C$25:$C$33,$D$25:$D$33=F25))

效果如下图所示：


使用 FILTER() 函数将每个组别对应姓名筛选出来，作为 TEXTJOIN() 函数的第 3 个参数，第 1 个参数分隔符设置为“、”符号，第 2 个参数设置为 TRUE（忽略空值），即可把查询到的所有人员连接到一个单元格。

【实例 4】根据明细生成打印标签。在 G38 单元格输入公式：

=TEXTJOIN(CHAR(10),TRUE,$B$37:$E$37&"："&B38:E38)

效果如下图所示：

• 第 1 个参数分隔符设置为 CHAR(10)，返回的换行符作为每组数组之间的分隔符；
• 第 2 个参数设置为 TRUE（忽略空值），引用 B37:E37 单元格区域，使用 & 运算符连接“:”符号，再使用 & 运算符连接 B38:E38 单元格区域，将每个标题和对应数据进行连接，因为公式需要向下填充，所以 B37:E37 单元格区域需要设置绝对引用，将公式返回结果作为 TEXTJOIN 函数的第 3 个参数。

输入公式后，在“开始”选项卡中单击“换行”按钮，合并的数据即可换行显示。

【实例 5】使用数组分隔符，连接省、市、区/县到一个单元格。在 F48 单元格输入任意一个公式：

=TEXTJOIN($C$47:$D$47,TRUE,C48:E48) =TEXTJOIN({"省","市"},TRUE,C48:E48)

效果如下图所示：


当需要使用多种符号连接字符串时，可以将TEXTJOIN函数的第1个参数分隔符指定一个单元格区域或数组，函数将数组中多个值依次作为分隔符连接字符串。

TEXTJOIN()注意事项

使用 TEXTJOIN() 函数连接字符串时，如果结果字符串长度大于 32 767，函数返回错误值 #VALUE!。在 B4 单元格输入公式：

=TEXTJOIN("-",TRUE,REPT("测",32767),1)

效果如下图所示：