WPS SHEETSNAME()函数用法详解（附带实例）

SHEETSNAME() 为 WPS 独有函数，SHEETSNAME() 函数可以返回引用中的工作表名称，语法格式如下：

=SHEETSNAME([参照区域]，[结果方向]，[工作表范围])

参数说明如下：

• 参照区域：省略参数时，默认值（公式所在工作簿所有显示的工作表名称）；
• 结果方向：省略参数时，默认值（0）；
• 工作表范围：
  • 0 – 包含当前工作表；
  • 1 – 不包含当前工作表；
  • 省略参数时，默认值（0）。

【实例 1】制作工作表目录。在 C5 单元格输入公式：

=SHEETSNAME(,1)

效果如下图所示：


使用 SHEETSNAME() 函数，省略第 1 个参数，第 2 个参数设置为 1（行方向），SHEETSNAME() 函数即可返回当前工作簿所有工作表名称。

在 B5 单元格输入公式：

=SEQUENCE(ROWS(C5#))

效果如下图所示：


使用 ROWS() 函数引用“工作表名称”公式所在的 C5 单元格，在单元格地址后添加#运算符可以获取该单元格公式返回的数组结果，ROWS() 函数即可返回引用单元格区域或数组的总行数，将返回值作为 SEQUENCE() 函数的第 1 个参数，即可根据生成指定行数的序号。

在 D5 单元格输入公式，如下图所示：

=HYPERLINK("#'"&C5#&"'!A1","转到")

效果如下图所示：

使用 HYPERLINK() 函数，第 1 个参数依次将#'、“工作表名称”公式所在的 C5# 单元格、'!A1拼接，作为超链接地址，第 2 个参数显示内容设置“转到”，即可为每个工作表添加超链接。

【实例 2】制作工作表目录（连续多个工作表名称）。在 C15 单元格输入公式：

=SHEETSNAME(研发部:市场部!A1,1)

效果如下图所示：


SHEETSNAME() 函数的第 1 个参数引用“研发部”至“市场部”的 A1 单元格，SHEETSNAME() 函数即可返回“研发部”开始至“市场部”结束之间的所有工作表名称。

也可省略 SHEETSNAME() 函数的第 1 个参数，返回所有工作表名称后，使用 TAKE、DROP、FILTER 等函数，根据位置或名称截取、删除、筛选需要的工作表名称，在 C23 单元格输入公式：

=DROP(SHEETSNAME(,1),2)

效果如下图所示：


使用 SHEETSNAME() 函数返回所有工作表名称后，使用 DROP() 函数将前 2 行的工作表名称删除。

SHEETSNAME()函数注意事项

1) SHEETSNAME() 函数只返回引用中显示的工作表名称，当工作表隐藏后，SHEETSNAME() 函数将无法返回该工作表名称。

在 C5 单元格输入公式：

=SHEETSNAME(研发部:财务部!A1,1)

效果如下图所示：


2) 当 SHEETSNAME() 函数引用中的工作表全部隐藏时，SHEETSNAME() 函数将返回错误值 #N/A，如下图所示：